home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
64'er
/
64ER_CD.iso
/
92xx
/
9206b.d64
/
b-copper 1.asc
< prev
next >
Wrap
Text File
|
1995-03-30
|
2KB
|
75 lines
;***************************************
;** BORDER-COPPERBARS (W) '92 BY PIT **
;***************************************
*= $1000 ;STARTADRESSE $1000
SEI ;IRQ SETZEN
LDA #<START ;VEKTOREN
STA $0314 ;AUF EIGENE
LDA #>START ;ROUTINE
STA $0315 ;VERBIEGEN
LDA #$01 ;NUR RASTER-IRQ
STA $D01A ;ZULASSEN
LDA $D011 ;Y-SCROLL REGISTER
AND #$7F ;AUF ORIGINAL-WERT
STA $D011 ;SETZEN
LDA #$00 ;GHOST-BYTE
STA $3FFF ;LOESCHEN
CLI ;IRQ-FLAG LOESCHEN
RTS ;ZURUECK
START LDA $DC0D ;IRQ VON DER
BMI BORDER ;CIA ODER VOM VIC?
LDA $D019 ;IRR LOESCHEN
STA $D019 ;
JMP $EA81 ;UND ZUM ALTEN IRQ
;--- --- --- --- --- --- --- --- --- ---
BORDER LDA #$F0 ;RASTERSTRAHL AUF
RZY1 CMP $D012 ;POSITION $F0 ??
BNE RZY1 ;
LDX #$21 ;WARTESCHLEIFE
RZY2 DEX ;ZUM AUSTIMEN
BNE RZY2 ;
LDX #$00 ;
RZY3 TXA ;AKKU
AND #$07 ;VERKNUEPFEN
ORA #$18 ;(KEIN TEXT)
LDY COLORS,X;FARBE LADEN
STA $D011 ;VERKNUEPFTER WERT
;IN $D011 SCHREIBEN
STY $D020 ;UND FARBEN IN
STY $D021 ;DIE FARBREGISTER
JSR WAIT ;AUSTIMEN
JSR WAIT ;AUSTIMEN
INX ;
CPX #$28 ;SCHON ALLE FARBEN?
BNE RZY3 ;
LDA #$00 ;BILDSCHIRM
STA $D020 ;AUF SCHWARZ
STA $D021 ;SETZEN
JMP $EA31 ;ALTER IRQ
WAIT BIT $FF ;3 ZYKLEN +
NOP ;2 ZYKLEN WARTEN
RTS ;UND ZURUECK
;--- --- --- --- --- --- --- --- --- ---
COLORS .BYTE $06,$00,$06,$04,$00,$06
.BYTE $04,$0E,$03,$00,$06,$04
.BYTE $0E,$03,$07,$00,$06,$04
.BYTE $0E,$03,$07,$01,$00,$06
.BYTE $04,$0E,$03,$07,$01,$07
.BYTE $03,$0E,$04,$06
;--- --- --- --- --- --- --- --- --- ---